CPL語言

function Euler [function Fct, real Eps, integer Tim] = result of
    || Euler computes the sum of Fct[i] fo​r i from zero up to infinity by 
    || means of a suitably refined Euler transformation. The summation is
    || stopped as soon as Tim ti​mes i​n succession the absolute value of 
    || the terms of the transformed series are found to be less than Eps.
    || Hence, one should provide a fu​nction Fct with one integer argument,
    || an upper bound Eps, and an integer Tim. The output is the sum Sum.
    || Euler is particularly efficient i​n the ca​se of a slowly convergent
    || or divergent alternating series.
    §1 dec §1.1 real Mn, Ds, Sum
                integer i, t
                index n = 0
                m = Array [real, (0, 15)] §⃒1.1
       i, t, m[0] := 0, 0, Fct[0]
       Sum := m[0]/2
       §1.2 i := i + 1
            Mn := Fct[i]
            for k = step 0, 1, n do
                m[k], Mn := Mn, (Mn + m[k])/2
            test Mod[Mn] < Mod[m[n]] ∧ n < 15
                then do Ds, n, m[n+l] := Mn/2, n + 1, Mn
                or do Ds := Mn
            Sum := Sum + Ds
            t := (Mod[Ds] < Eps) → t + 1, 0 §⃒1.2
       repeat while t < Tim
       result := Sum §⃒1.